Atmel公司的ATMEGA48是一款高性能、低功耗的8 位AVR微處理器，使用先進的RISC 結構，大多數(shù)指令的執(zhí)行時間為單個時鐘周期，所以運算速度更快。兩個具有獨立預分頻器和比較器功能的8 位定時器/ 計數(shù)器；一個具有預分頻器、比較功能和捕捉功能的16 位定時器/ 計數(shù)器；具有獨立振蕩器的實時計數(shù)器RTC；六通道PWM；8路10 位ADC(TQFP 與MLF 封裝)[ 6路10 位ADC( PDIP 封裝)]；可編程的串行USART 接口；可工作于主機/ 從機模式的SPI 串行接口；面向字節(jié)的兩線串行接口；具有獨立片內振蕩器的可編程看門狗定時器；片內模擬比較器；引腳電平變化可引發(fā)中斷及喚醒MCU等。

    其具有的下面特點無論從編程、自編程和加密等方面都給用戶提供了很大的方便。4K字節(jié)的系統(tǒng)內可擦寫10,000 次的可編程Flash；具有獨立鎖定位的可選Boot 代碼區(qū)，通過片上Boot程序實現(xiàn)系統(tǒng)內編程；256字節(jié)的擦寫100,000 次的EEPROM；512字節(jié)的片內SRAM，可以對鎖定位進行編程以實現(xiàn)用戶程序的加密。

    Maxim公司的8腳串行實時時鐘日歷芯片DS1302，體積小、與單片機接口簡單、工作電壓范圍寬(2.5~5.5V)、功耗低、接口容易、占用CPU I/O口線少、可對時鐘芯片備份電池進行涓流充電等特點。所以應用方便，被很多設計者所青睞。

圖1  ATMEGA48與DS1302的電路連接

 
    筆者利用這兩種芯片，設計了實時時鐘，實時數(shù)據(jù)采集和定時控制系統(tǒng)?，F(xiàn)就DS1302與ATMEGA48的應用介紹給大家。

    由于ATMEGA48有可選的內部振蕩器，所以只需接通電源即可；DS1302需要一個32768Hz的晶振，和一個備用電池?？梢钥闯鼋Y構很簡單(由于本文只介紹ATMEGA48和DS1302的應用，所以其余的顯示電路和數(shù)據(jù)采集電路均省略。)。

ATMEGA48與DS1302的通訊程序(ASM)

圖2  DS1302的時序

圖3  DS1302充電原理圖

DS1302的時序如圖2。
根據(jù)時序圖，給出下面的讀/寫程序：
讀出數(shù)據(jù)子程序如下：
  ;sbi portd,7 ;假設調用子程序以前已經保持rst為高
RDS:  clr r17   ;將取到的數(shù)據(jù)保存到R17中
  ldi r24,8
  sbi portd,6  ;sclk
RDS1: cbi portd,6  ;sclk 下降沿讀取數(shù)據(jù)
  nop
  IN R16,pind      ;從CPU I/O讀取數(shù)據(jù)
  nop
  sbi portd,6  ;sclk
  BST R16,5  ;復制PIND.5到T
  LSR R17
  BLD R17,7  ;復制T到R17.7
  dec r24
  CPI R24,0
  BRNE  RDS1
  RET

    注：ATMEGA48 I/O口有三個寄存器分別是：數(shù)據(jù)寄存器- PORTx、數(shù)據(jù)方向寄存器- DDRx 和端口輸入引腳- PINx。I/O作為數(shù)據(jù)輸入使用時，讀取數(shù)據(jù)命令應為 IN Rd,PINx，如果使用IN Rd,PORTx則讀取到的是I/O口的狀態(tài)，盡管將DDRx設置成數(shù)據(jù)輸入。特別注意的是，讀取軟件賦予引腳電平和執(zhí)行讀取指令in 之間至少有一個時鐘周期的間隔，文中用nop間隔。

寫入數(shù)據(jù)(命令/地址)子程序如下：
  ;ldi R17,data ;假設要寫入的數(shù)據(jù)已經存放到R17中
  ;sbi portd,7 ;假設調用子程序以前已經保持rst為高
WDS:  ldi r24,8
WDS1: cbi portd,6  ;sclk
  in r16,portd  ;讀入D口狀態(tài)
  BST R17,0  ;將R17.0復制到T
  BLD R16,5  ;將T復制到R16.5
  nop
  out portd,r16 ;寫數(shù)據(jù)到portd(R16.5->portd.5)
  sbi portd,6  ;sclk
  lsr r17
   dec r24
  CPI R24,0
  BRNE WDS1  
  RET

    關于命令字節(jié)的說明。DS1302命令字節(jié)由8位組成，BIT 0 為1時，讀取數(shù)據(jù)，為0時寫入數(shù)據(jù)。BIT 1-5 為地址。BIT 6 為1時指向31個RAM，為0 時指向時鐘寄存器。BIT 7 必須為1，為0時將使DS1302停止。
DS1302的控制寄存器的第七位是寫保護位，所以在寫入數(shù)據(jù)前應該將其關閉，并在寫數(shù)據(jù)完畢后將其使能。下面是一段完整的設置分的程序。
......
ldi r19,0x43  ;假設當前時間為43分，DS1302時間寄存器保存的數(shù)據(jù)為10進制數(shù)十六進制存儲。
ldi r18,0x82  ;寫分 命令
ldi r27,0x00  ;x H
ldi r26,19  ;x L    在這里使用間接尋址，所以只需改變R19的數(shù)據(jù)即可。
......
WRITE_DS1302:
  cbi portd,7
  cbi portd,6
  sbi portd,7 
  ldi r17,0x8e        ;控制寄存器en_WRITE
  rCALL  WDS   
  ldi r17,0    ;寫操作前WP=0
  rCALL  WDS 
  mov r17,r18          ;寫秒 分 時 日 月 星期 年 地址
        rCALL  WDS
  ld r17,x      ;寫秒 分 時 日 月 星期 年(R19中的數(shù)據(jù))
        rCALL  WDS 
  cbi portd,7
  cbi portd,6
  sbi portd,7
  ldi r17,0x8e        ;控制寄存器un_en_WRITE
  rCALL  WDS
  ldi r17,0x80   ;寫操作前WP=1
  rCALL  WDS 
  cbi portd,7    
  RET

    同樣，下面給出了一個完整的讀取分的程序
ldi r18,0x83  ;讀分 命令
ldi r27,0x00  ;x H
ldi r26,19  ;x L    將取到的數(shù)據(jù)存儲到R19中。
READ_DS1302:
  cbi portd,7
  cbi portd,6
  sbi portd,7
  mov r17,r18         ;寫秒 分 時 日 月 星期 年 地址
     rCALL  WDS 
     rCALL  RDS
  st x,r17  ; 保存數(shù)據(jù)到R19
  cbi portd,7
  RET

    整合寫和讀分的程序，改變R18的內容就可以實現(xiàn)“秒、分、時、日、月、星期、年”的讀寫，寫操作時只需改變R19的內容就可以將新的數(shù)據(jù)寫入，讀操作時直接讀取R19的內容即可。也可以通過此程序直接來對31個RAM進行數(shù)據(jù)讀取。

DS1302的充電功能

    DS1302的涓流充電功能也是非常方便的，同時又是其非常重要的一個功能，所以簡單介紹一下其使用。其原理框圖如圖3。

    DS1302有一個單獨的寄存器控制涓流充電。BIT7:BIT4是涓流充電功能的選擇器，只有當它們被設置成1010才能夠將其使能。使用DS(BIT3和BIT2)可以在一個和兩個二極管之間選擇；使用RS(BIT1和BIT0)可以選擇兩個電源(Vcc1和Vcc2)之間的電阻，這兩個選擇器共同使用來幫助您得到所需要的電流。

結語

    通過這一實踐，表明應用DS1302在測控系統(tǒng)中的數(shù)據(jù)記錄，其軟硬件設計簡單，時間記錄準確。同時由于ATMEGA48的高速度，大數(shù)據(jù)吞吐，給實際應用帶來了很大方便。由于筆者水平有限，僅將應用筆記供大家參考。

參考文獻：
1.  8-bit AVR Microcontroller with 4K Bytes In-System Programmable Flash (data sheet)
2.  DS1302 - Trickle Charge Timekeeping Chip (data sheet)