有的單片機(jī)(如8098)有專門的復(fù)位指令，某些增強(qiáng)型MCS-51系統(tǒng)單片機(jī)雖然沒有復(fù)位指令，但片內(nèi)集成了WATCHDOG電路，故抗干擾也不成問題。而普及型MCS-51系列單片機(jī)(如8031和8032)既然無復(fù)位指令，又不帶硬件WATCHDOS，如果沒有外接硬件WATCHDOG電路，就必須采用軟件抗干擾技術(shù)。常用的軟件抗干擾技術(shù)有：軟件陷阱、指令冗余、軟件WATCHDOG等，它們的作用是在系統(tǒng)受干擾時(shí)能及時(shí)發(fā)現(xiàn)，再用軟件的方法使系統(tǒng)復(fù)位。所謂軟件復(fù)位就是用一系列指令來模仿復(fù)位操作，這就是MCS-51系列單片機(jī)所特有的軟件復(fù)位技術(shù)。

現(xiàn)用一簡(jiǎn)單的實(shí)驗(yàn)說明，實(shí)驗(yàn)電路如附圖所示。接于仿真插座P1.0的發(fā)光二極管LED0用來表示主程序的工作情況，接于P1。1的發(fā)光二極管LED1用于表示低級(jí)中斷子程序的工作情況，接于P1。2的發(fā)光二極管LED2用來表示高級(jí)中斷子程序的工作情況，接于P3。2口的按鈕用來設(shè)立干擾標(biāo)志，程序檢測(cè)到干擾標(biāo)志后故意進(jìn)入死循環(huán)或掉進(jìn)陷井，模仿受干擾的情況，從而檢驗(yàn)各種復(fù)位方法的實(shí)際效果。寮驗(yàn)初始化程序如下：

ORG　0000H

STAT：　LJMP　MAIN　;復(fù)位入口地址

LJMP　PX0　;按鈕中斷向量(低級(jí)中斷)

ORG　000BH

LJMP　PT0　;t0中斷向量(低級(jí)中斷)

ORG　001BH

LJMP　PT1　;T1中斷向量(高級(jí)中斷)

ORG　0030H

MAIN：

CLR　EA

MOV　SP，#7

MOV　P1，#0FFH

MOV　P3，#0FFH

MOV　TMOD，#11H

CLR　00H　;干擾標(biāo)志初始化

SETB　ET0

SETB　ET1

SETB　EX0

SETB　PT1

SETB　TR0

SETB　TR1

SETB　EA

LOOP：　CPL　P1.0　;主程序發(fā)光二極管LED閃爍

MOV　R6，#80H

MOV　R7，#0

TT1：

DJNZ　R7，TT1

DJNZ　R6，TT1

SJMP　LOOP

PX0：

SETB　00H　;設(shè)立干擾標(biāo)志，模擬發(fā)生干擾

PT0：　CPL　P1.1　;低級(jí)中斷程序發(fā)光二極管LED1閃爍

RETI

PT1：　CPL　P1.2　;高級(jí)中斷程序發(fā)光二極管LED2閃爍

RETI

END

實(shí)驗(yàn)步驟如下：

1.　按上述程序啟動(dòng)執(zhí)行，三個(gè)發(fā)光二極管都應(yīng)閃爍(否則應(yīng)先排除故障)，表示主程序和各中斷子程序正常。因模擬干擾標(biāo)志未加檢測(cè)，故不受按鈕影響。

2.　修改主程序如下，按下按鈕后主程序即掉入死循環(huán)中。

LOOP：　CPL　P1.0

MOV　R6，#80H

MOV　R7，#0H

TT1：　DJNZ　R7，TT1

DJNZ　R6，TT1

JNB　00H，LOOP　;受干擾否?

STOP：　LJMP　STOP　;掉入死循環(huán)。

這時(shí)可以看到，主程序停止工作(LED0停止閃爍)，而兩個(gè)中斷子程序繼續(xù)運(yùn)行(LED1和LED2繼續(xù)閃爍)。

3.　將定時(shí)器T1妝作軟件WATCHDOG，將30H單元用作軟件WATCHDOG計(jì)數(shù)器。主程序中加入一條復(fù)位軟件WATCHDOG的指令。

LOOP：　CPL　P1.0

MOV　30H，#0　;復(fù)位軟件WATCHDOG計(jì)數(shù)器

LOOP：　CPL　P1.0

MOV　R6，#80H

MOV　R7，#0H

TT1：　DJNZ　R7，TT1

DJNZ　R6，TT1

JNB　00H，LOOP　;受干擾否?

STOP：　LJMP　STOP　;掉入死循環(huán)。

T1中斷子程序修改如下：

PT1：　CPL　P1.2　;高級(jí)中斷程序發(fā)光二極管閃爍

INC　30H

MOV　A，30H

ADD　A，#0FDH

JC　ERR　;達(dá)到3次否?

RETI

ERR：　LJMP　STAT　;軟件WATCHDOG動(dòng)作

當(dāng)按下按鈕前，程序正常運(yùn)行(三個(gè)LED全閃)。按下按鈕后，主程序能迅速恢復(fù)工作，但兩個(gè)中斷子程序被封鎖，不再工作。過程如下：主程序檢測(cè)到干擾后進(jìn)入死循環(huán)，不能執(zhí)行復(fù)位30H單元的操作，T1中斷使30H不斷增值，計(jì)數(shù)到3時(shí)，軟件WATCHDOG執(zhí)行動(dòng)作，執(zhí)行一條LJMP指令，使程序從頭執(zhí)行。MAIN過程中清除了干擾標(biāo)志(表示干擾已經(jīng)過去)，使主程序迅速恢復(fù)工作。按理說MAIN過程中也重新設(shè)定了各個(gè)中斷，并開放了它們，為什么中斷不能恢復(fù)工作呢?這是因?yàn)橹袛嗉せ顦?biāo)志的復(fù)位工作被遺忘了，因?yàn)樗鼪]有明確的位地址可供編程，直接轉(zhuǎn)向0000H地址并不能完成真正的復(fù)位。軟件復(fù)位是使用軟件陷井和軟件WATCHDOG后必須進(jìn)行的工作，這時(shí)程序出錯(cuò)完全有可能發(fā)生中斷子程序中，中斷激活標(biāo)志已置位，它將阻止同級(jí)中斷響應(yīng)。由于軟件WATCHDOG是高級(jí)中斷，它將阻止所有中斷響應(yīng)。由此可見，清除中斷激活標(biāo)志的得要性，很多文獻(xiàn)的作者回為沒有認(rèn)識(shí)到這一點(diǎn)進(jìn)入誤區(qū)。

4.　在所有指令中，只有RETI指令能清除中斷激活標(biāo)志。出錯(cuò)處理程序ERR主要是完成這一功能，其它的善后工作交由復(fù)位后的系統(tǒng)去完成。為此，我們重新設(shè)計(jì)T1中斷子程序如下所示：

PT1：　CPL　P1.2　;高級(jí)中斷程序發(fā)光二極管閃爍

INC　30H　;軟件WATCHDOG計(jì)數(shù)器增值

MOV　A，30H

ADD　A，#0FD

JC　ERR　;達(dá)到3次否?

RETI

ERR：　CLR　EA　;關(guān)中斷

CLR　A　;準(zhǔn)備復(fù)位地址(0000H)

PUSH　ACC

PUSH　ACC

RETI　;清除中斷激活標(biāo)志并復(fù)位

這段程序先關(guān)中斷，以便后續(xù)處理能順利進(jìn)行，然后用RETI指令替代LJMP指令，從而既清除了中斷激活標(biāo)志又完成了轉(zhuǎn)向0000H的任務(wù)。按這樣改好后程序再運(yùn)行，結(jié)果仍不理想：按下按鈕后，有時(shí)只有主程序和高級(jí)中斷子程序能迅速恢復(fù)正常，而低級(jí)中斷仍有被關(guān)閉的可能。如果按如下方法把干擾轉(zhuǎn)移到低級(jí)中斷中，則按下按鈕后低級(jí)中斷必然被關(guān)閉：

LOOP：　CPL　P1.0

MOV　R6，#80H

MOV　R7，#0H

TT1：　DJNZ　R7，TT1

DJNZ　R6，TT1

SJMP　LOOP

PT0：　CPL　P1.1

JB　00H，STOP

RETI

STOP：　LJMP　STOP　;掉入死循環(huán)。

仔細(xì)分析后可能得出結(jié)論：當(dāng)軟件WATCHDOG是嵌套在低級(jí)中斷中起作用時(shí)，復(fù)位后只清除了高級(jí)中斷激活標(biāo)志，低級(jí)中斷標(biāo)志仍然被置位，從而使低級(jí)中斷一直被關(guān)閉。

5.　修改出錯(cuò)處理如下：

ERR：　CLR　EA　;正確的軟件復(fù)位入口

MOV　66H，#0AAH　;重建上電標(biāo)志

MOV　67H，#55H

MOV　DPTR，#ERR1　;準(zhǔn)備第一次返回地址

PUSH　DPL

PUSH　DPH

RETI　;清除高級(jí)中斷激活標(biāo)志

ERR1：　CLR　A

PUSH　ACC

PUSH　ACC

RETI　;清除低級(jí)中斷激活標(biāo)志

這時(shí)，必須執(zhí)行兩次RETI，才能到達(dá)0000H，以保證清除全部中斷激活標(biāo)志，達(dá)到和硬件復(fù)位相同的效果。同樣，軟件陷井也必須由下列三條指令

NOP

NOP

LJMP　STAT

改成：

NOP

NOP

LJMP　ERR

才能達(dá)到目的。

當(dāng)主程序受到干擾被軟件陷阱捕獲時(shí)，中斷標(biāo)志并未置位，執(zhí)行ERR過程中，RETI指令等效于RET指令，同樣可以達(dá)到軟件復(fù)位的目的。有興趣的讀者可以將軟件陷阱代替死循環(huán)，分別用LJMP　STAT和LJMP　ERR1來替代LJMP　ERR，再將干擾檢測(cè)分別設(shè)在低級(jí)中斷和主程序中，實(shí)驗(yàn)結(jié)果必然證明同：只有LJMP　ERR才能萬無一失地實(shí)現(xiàn)軟件復(fù)位，使系統(tǒng)擺脫干擾同，恢復(fù)正常。在MCS-51單片機(jī)的軟件復(fù)位過程中，必須連續(xù)執(zhí)行兩次中斷返回指令RETI。