13.5 復位和初始化

任何運行在實際硬件上的嵌入式應用程序，都必須在啟動時實現一些基本的系統(tǒng)初始化。本節(jié)將對此予以詳細討論。

13.5.1 初始化序列

圖13.14顯示了一個適用于ARM嵌入式系統(tǒng)的初始化序列。

圖13.14 ARM嵌入式系統(tǒng)的初始化序列

系統(tǒng)啟動時立即執(zhí)行復位處理程序，然后進入$Sub$$main()的代碼執(zhí)行。

復位處理程序是用匯編語言編寫的代碼塊，它在系統(tǒng)復位時執(zhí)行，完成系統(tǒng)初始化操作。對于具有局部存儲器的內核，如Caches、緊密藕荷存儲器（TCM）、存儲管理單元（MMU）和存儲器保護單元（MPU）等，在初始化過程這一階段完成必要的配置。復位處理程序在執(zhí)行之后，通常跳轉到__main以開始C庫的初始化序列。

13.5.2 向量表

所有的ARM系統(tǒng)都有一個向量表（vector table）。向量表不是初始化序列的一部分，但是對每個要處理的異常，它必須存在。這些地址通常包含以下形式的跳轉指令。

· B<address>：該條指令實現了相對于pc的跳轉

· LDR pc，[pc，offset]：這條指令將異常處理程序的入口地址從存儲器裝載到pc。該地址是一個32位的絕對地址。由于有額外的存儲器訪問，裝載跳轉地址會使分支跳轉到特定處理程序，給系統(tǒng)執(zhí)行帶來延時。不過，可以使用這種方法跳轉到存儲空間內的任意地址。

· MOV pc，＃immediate：將一個立即數復制到pc。使用該指令可以跨越整個地址空間，但是受到地址對齊問題的限制。這個地址必須由8位立即數循環(huán)右移偶數次得到。

另外，也可以在向量表中使用其他類型的指令。例如，FIQ處理程序可以從地址0x1c處開始執(zhí)行。因為它位于向量表的最后，這樣FIQ處理程序就可以不用跳轉，立即從FIQ向量地址處開始執(zhí)行。

下面的例子顯示了一個使用LDR指令的向量表裝載過程。

;**********************************

;* VECTOR TABLE *

;**********************************

AREA vectors, CODE

ENTRY

; 定義標準的ARM向量表

INT_Vectors

LDR PC, INT_Reset_Addr

LDR PC, INT_Undef_Addr

LDR PC, INT_Software_Addr

LDR PC, INT_Prefetch_Addr

LDR PC, INT_Data_Addr

LDR PC, INT_Reserved_Addr

LDR PC, INT_IRQ_Addr

LDR PC, INT_FIQ_Addr

在向量表的入口處要有ENTRY標識。該標識通知鏈接程序該代碼是一個可能的入口點，因而在鏈接時，不能被清除。

13.5.3 ROM/RAM重映射

啟動時，0x0處必須要有一條有效指令，因此，復位時0x0000地址必須為非易失性存儲器，如ROM或FLASH。

注意

有些系統(tǒng)是從0xffff0000處開始執(zhí)行的，對于這樣的系統(tǒng)，地址0xffff0000處必須為非易失性存儲器。

可以將ROM定位在0x0處。但是，這樣配置有幾個缺點。首先ROM存取速度通常較RAM要慢，當跳轉到異常處理程序時，系統(tǒng)性能可能會大受影響。其次，將向量表放于ROM中，運行時不能修改。

存儲器地址重映射（Memory Remap）是當前很多先進控制器所具有的功能。所謂地址重映射就是可以通過軟件配置來改變存儲器物理地址的一種機制或方法。

當一段程序對運行自己得存儲器進行重映射時，需要特別注意保證程序執(zhí)行流程在重映射前后的承接關系。實現重映射的關鍵就是要使程序指針在remap以后能繼續(xù)往下得到正確的指令。本書中介紹兩種實現重映射的機制，不同的系統(tǒng)可能會有多種靈活的remap方案，用戶在具體實現時要具體分析。

1．先搬移后映射（Remap after Copy）

圖13.15顯示一種典型的存儲器地址重映射情況。

圖13.15 ROM/RAM重映射（1）

原來RAM和ROM各有自己的地址，進行重映射以后RAM和ROM的地址都發(fā)生了變化。這種情況下，可以采用以下方案。

① 上電后，從0x0地址的ROM開始往下執(zhí)行。

② 根據映射前的地址，對RAM進行必要的代碼和數據拷貝。

③ 拷貝完后，進行remap操作。

④ 因為RAM在remap前準備好了內容，使得PC指針能繼續(xù)在RAM里取到正確的指令。

2．先映射后搬移（Copy after Remap）

系統(tǒng)上電后的缺省狀態(tài)是0x0地址上放有ROM。這塊ROM有兩個地址：從0起始和從0x10000起始，里面存儲了初始化代碼。當進行地址remap以后，從0x0起始的地址被定向到RAM上，ROM則只保留有惟一的從0x10000起始的地址。

如果存儲在ROM里的復位異常處理程序（Reset-Handler）一直在0x0～0x4000的地址上運行，則當執(zhí)行完remap以后，下面的指令將從RAM里預取，這必然會導致程序執(zhí)行流程的中斷。根據系統(tǒng)特點，可以用下面的辦法來解決這個問題。

① 上電后系統(tǒng)從0x0地址開始自動執(zhí)行，設計跳轉指令在remap發(fā)生前使PC指針指向0x10000開始的ROM地址中去，因為不同地址指向的是同一塊ROM，所有程序能夠順利執(zhí)行。

② 這時候0x0～0x4000的地址空間空閑，不被程序引用，執(zhí)行remap后把RAM引進。因為程序一直在0x10000起始的ROM空間里運行，remap對運行流程沒有任何影響。

③ 通過在ROM里運行的程序，對RAM進行相應的代碼和數據拷貝，完成應用程序運行的初始化。

圖13.16顯示了ROM和RAM重映射的第二種解決方案。

圖13.16 ROM/RAM重映射（2）

該ROM與RAM地址重映射的方法可以應用于任何具有ROM/RAM重映射機制的平臺，但是內存重映射的地址根據具體平臺的不同而不同。

圖13.16顯示的地址重映射例子中，第一條指令實現從ROM臨時地址（0x0地址）到實際ROM的跳轉。然后，控制寄存器的重映射位，清除ROM的臨時地址設置。該代碼通常在系統(tǒng)復位后立即執(zhí)行。重新映射必須在執(zhí)行C庫初始化代碼前完成。

在具有MMU的系統(tǒng)中，可通過在系統(tǒng)啟動時配置MMU來實現重映射。

下面的例子顯示了在ARM的Integrator開發(fā)板上實現的ROM/RAM重映射過程。

; --- Integrator CM control reg

CM_ctl_reg EQU 0x1000000C ;定義CM控制寄存器地址

Remap_bit EQU 0x04 ;CM控制寄存器重映射掩碼

ENTRY

;復位異常處理程序開始

; 執(zhí)行跳轉指令，轉到實際的ROM執(zhí)行

LDR pc, =Instruct_2

Instruct_2

; 設置CM控制寄存器的重映射位

LDR r1, =CM_ctl_reg

LDR r0, [r1]

ORR r0, r0, #Remap_bit

STR r0, [r1]

; 重映射后，RAM在0x0地址

; 將向量表從ROM拷貝到 RAM (由 __main函數完成)

13.5.3 局部存儲器設置有關的考慮事項

許多ARM處理器內核具有片上存儲器系統(tǒng)，如MMU或MPU。這些設備通常是在系統(tǒng)啟動過程中進行設置并啟用的。因此，帶有局部存儲器系統(tǒng)的內核的初始化序列需要特別地考慮。

在前面所述的代碼啟動的過程中，__main中C庫初始化代碼負責建立代碼執(zhí)行時的內存映像，在跳轉到__main前，必須建立處理器內核的運行時存儲器視圖。這就是說，在復位處理程序中必須設置并啟用MMU或MPU。

另外，在跳轉到__main前（通常在MMU/MPU設置前），必須啟用緊耦合存儲器TCM（Tightly coupled Memory），因為在通常情況下都是采用分散加載方法將代碼和數據裝入TCM。當TCM啟用后，用戶不必存取由TCM屏蔽的存儲器。

在跳轉到__main前，如果啟用了Cache，可能還會遇到Cache一致性的問題，__main中的函數將程序代碼從其加載域拷貝到執(zhí)行域，在此過程中將指令作為數據進行處理。這樣，一些指令可能被放入數據Cache中，在執(zhí)行這些指令時，由于找不到地址路徑而產生錯誤。為了避免Cache一致性的問題，在C庫初始化序列執(zhí)行完成后再啟用Cache。

13.5.4 棧指針初始化

在程序的初始化代碼中，用戶必須要為處理器用到的各種模式設置堆棧，也就是說，復位處理程序必須為應用程序所使用的任何執(zhí)行模式的棧指針分配初始值。

下面的例子顯示了如何在初始化代碼中啟用不同模式下的堆棧。

; 啟用系統(tǒng)模式堆棧

LDR r2,INT_System_Stack ;將系統(tǒng)堆棧的全局變量放到r2中

STR sp,[r2] ;將系統(tǒng)堆棧指針存儲到系統(tǒng)模式下的sp

; 啟用系統(tǒng)堆棧限制 (為ARM編譯器的堆棧檢測做準備)

SUB r1,sp,#SYSTEM_STACK_SIZE ;跳轉堆棧指針

BIC r1,r1,#0x03 ;4字節(jié)對齊

MOV r10,r1 ;將堆棧的限制放入r10寄存器（AAPCS規(guī)則）

LDR r2,INT_System_Limit ;得到堆棧限制全局變量地址

STR r1,[r2] ;將堆棧限制存入全局變量

; 切換到IRQ模式

MRS r0,CPSR ;得到當前的CPSR值

BIC r0,r0,#MODE_MASK ;清除模式位

ORR r1,r0,#IRQ_MODE ;設為IRQ模式

MSR CPSR_cxsf,r1 ;切換到IRQ模式

;啟用IRQ模式堆棧

LDR sp,=INT_Irq_SP ;將IRQ模式堆棧指針放入sp_irq

; 切換到FIQ

ORR r1,r0,#FIQ_MODE ;設置FIQ模式位

MSR CPSR_cxsf,r1 ;切換到FIQ模式

; Set-up FIQ stack

LDR sp,=INT_Fiq_SP ;得到FIQ模式指針

; 切換到Abort模式

ORR r1,r0,#ABT_MODE ;設置Abort模式位

MSR CPSR_cxsf,r1 ;切換到ABT模式

; 啟用Abort堆棧

LDR sp,=INT_Abort_SP

; 切換到未定義異常模式

ORR r1,r0,#UNDEF_MODE

MSR CPSR_cxsf,r1

;啟用未定義指令模式堆棧

LDR sp,=INT_Undefined_SP

; 啟用系統(tǒng)/用戶堆棧

……

……

為了設置棧指針，進入每種模式（中斷禁用）并為棧指針分配適合的值。要利用軟件棧檢查，也必須在此設置棧限制。

復位處理程序中設置的棧指針和棧限制值由C庫初始化代碼作為參數自動傳遞給__user_initial_stackheap()。因此，不允許__user_initial_stackheap()更改這些值。

下面的例子顯示了如何實現__user_initial_stackheap()，該段代碼可以和上面的堆棧指針設置程序配合使用。

IMPORT heap_base

EXPORT __user_initial_stackheap()

__user_initial_stackheap()

; 程序中指定?；刂坊蛟诿枋鑫募兄付ㄔ摰刂?/p>

LDR r0,=heap_base

; r1 contains SB value

MOV pc,lr

13.5.5 硬件初始化

一般情況下，系統(tǒng)初始化代碼和主應用程序是分開的。系統(tǒng)初始化要在主應用程序啟動前完成。但部分與硬件相關的系統(tǒng)初始化過程，如啟用Cache和中斷，必須在C庫初始化代碼執(zhí)行完成后才能執(zhí)行。

為了在進入主應用程序之前，完成系統(tǒng)初始化，可以使用$sub和$super函數標識符在進入主程序之前插入一個例程。這一機制可以在不改變源代碼的情況下擴展函數的功能。

下面的例子說明了如何使用$sub和$super函數標識。鏈接程序通過調用$sub$$main()函數取代對main()的調用。所以用戶可以在自己編寫的$sub$$main()例程中啟用Cache或使能中斷。

extern void $Super$$main(void);

void $Sub$$main(void)

{

cache_enable(); // 使能caches

int_enable(); // 使能中斷

$Super$$main(); // 調用原來的main()函數

}

在$Sub$$main(void)函數中，鏈接程序通過調用$Super$$main()，使代碼跳轉到實際的main()函數。

在完成硬件初始化之后，必須考慮主應用程序運行在何種模式。如果應用程序運行在特權模式（Privileged mode），只需在退出復位處理程序前切換到適當的模式；如果應用程序運行在用戶模式下，要在完成系統(tǒng)初始化之后，再切換到用戶模式。模式的切換工作，一般在$Sub$$main(void)函數中完成。